Este es un ejemplo bastante completo: Formatea el texto y envía anexos. Funciona con la 6.5 de Notes pero no debería haber ningún problema con la 4.6

Public Function SendNotesMail(ByVal Receptor As String, ByVal Asunto As String, ByVal BodyText As String, ByVal WebLink As String, ByVal Anexo As String) As Boolean
Dim mailDb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'The current users notes mail database name
Dim mailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim Server As String 'The current users notes mail server name
Dim Espacio As Object
Dim EmbedObj As Object 'The embedded object (Attachment)
Dim RichStyle As Object
Dim RtItem As Object
Dim Opened As Boolean

Err.Clear
On Error GoTo NotesError
'Start a session to notes
Set Session = CreateObject("Notes.NotesSession")
Server = Session.GETENVIRONMENTSTRING("MailServer", True)
MailDbName = Session.GETENVIRONMENTSTRING("MailFile", True)
UserName = Session.UserName
Set mailDb = Session.GETDATABASE(Server, MailDbName)

'Set up the new mail document
Set mailDoc = mailDb.CREATEDOCUMENT
With mailDoc
.Form = "Memo"
.SendTo = Receptor
.Subject = Asunto
.DeliveryReport = "H"
.ReturnReceipt = "1"
.Importance = "1"
.Priority = "1"
.PostedDate = Now()
.DeliveryPriority = "H"
.From = UserName
End With

Set RichStyle = Session.CREATERICHTEXTSTYLE
RichStyle.Bold = True
RichStyle.PASSTHRUHTML = 0
Set RtItem = mailDoc.CREATERICHTEXTITEM("EnviarURL")
Call RtItem.APPENDSTYLE(RichStyle)
If WebLink <> "" Then
Call RtItem.APPENDTEXT(WebLink)
Call RtItem.ADDNEWLINE(2)
End If
RichStyle.Bold = False
Call RtItem.APPENDTEXT("Buenos días:")
Call RtItem.ADDNEWLINE(2)
Call RtItem.APPENDTEXT(BodyText)
Call RtItem.ADDNEWLINE(2)
Call RtItem.APPENDTEXT("Gracias.")
Call RtItem.COPYITEMTODOCUMENT(mailDoc, "Body")
mailDoc.SAVEMESSAGEONSEND = True
'Set up the embedded object and attachment and attach it
If Anexo <> "" Then
Set AttachME = mailDoc.CREATERICHTEXTITEM("Attachment")
Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Anexo, "Attachment")
End If
'Send the document
mailDoc.PostedDate = Now() 'Gets the mail to appear in the sent items folder
Call mailDoc.SEND(0, Receptor)
If Err.Number <> 0 Then
SendNotesMail = False
Else
SendNotesMail = True
End If

'Clean Up
Set mailDb = Nothing
Set mailDoc = Nothing
Set AttachME = Nothing
Set EmbedObj = Nothing
Set Session = Nothing
Set Espacio = Nothing
Exit Function

NotesError:
If Err.Number <> 0 Then
SendNotesMail = False
NumeroErr = Err.Number
DescripcionErr = Err.Description
End If
End Function

Espero que te sirva.
Saludos

Responder

Re: Re: Re: Re: Visual Basic y Lotus Notes

Enviado por f_alcon82 el día 25 de agosto de 2008

Hola yo tengo un problema.El envio de correos por VB lo hago desde una BD de access 2007 y me va todo perfecto menos la opcion de ponerlo en enviados, no me los guarda, me dice que el objeto no admite la propiedad de POSDATE, mi codigo es el siguiente:
Dim Maildb As Object \'The mail database
Dim UserName As String \'The current users notes name
Dim MailDbName As String \'THe current users notes mail database name
Dim maildoc As Object \'The mail document itself
Dim AttachME As Object \'The attachment richtextfile object
Dim session As Object \'The notes session
Dim EmbedObj As Object \'The embedded object (Attachment)

Set session = CreateObject(\"lotus.NotesSession\")

\'Con esto el objeto nos pregunta la contraseña de acceso a la cuenta
Call session.Initialize(\"\")
UserName = session.UserName

\'Abrimos la base de datos de correos en notes
\'en principio, funciona con una bbdd local
\'MailDbName = <path al archivo nsf>
\'o bien usando una genérica
MailDbName = \"names.nsf\"
Set Maildb = session.GETDATABASE(\"\", MailDbName)
If Maildb.ISOPEN = True Then
Else
Call Maildb.Open(\"\", MailDbName)
End If
\'Preparamos el mensaje
Set maildoc = Maildb.CREATEDOCUMENT
maildoc.APPENDITEMVALUE \"Form\", \"Memo\"
maildoc.APPENDITEMVALUE \"Subject\", Subject
maildoc.APPENDITEMVALUE \"Body\", BodyText
\'Preparamos el objeto embebido
If Attachment <> \"\" Then
Set AttachME = maildoc.CREATERICHTEXTITEM(\"Attachment\")
Set EmbedObj = AttachME.EmbedObject(1454, \"\", Attachment, \"Attachment\")
End If
\'Enviamos el documento
\'maildoc.PostedDate = Now() \'Hace que el correo aparezca en elementos enviados
maildoc.SaveMessageOnSend = True
maildoc.PutInFolder (\"$Sent\")
maildoc.SEND 0, Recipient
\'Eliminamos los objetos creados
Set Maildb = Nothing
Set maildoc = Nothing
Set AttachME = Nothing
Set session = Nothing
Set EmbedObj = Nothing

End Sub
Que debo hacer?

 

Responder